Veeam ONE: SQL Express Maximum Database Size Limitation

--Specify the new Retention Policy (how many months to keep)
DECLARE @RetentionPolicy_New int = 12
--
--StrictCleanup value of 0 is recommended for most environments.  Set to 1 for a more aggressive cleanup that will take longer.
DECLARE @StrictCleanup int = 0
-- 
--Do not modify anything below this line!--
IF (@RetentionPolicy_New not between 1 and 36) BEGIN RAISERROR ('ERROR: The Retention Policy value must be within range of 1-36 months',15,15); RETURN; END
DECLARE @RetentionPolicy int = (select top 1 coalesce(RetentionPolicyPeriod,12) from common.ServerSettings)
IF @RetentionPolicy > @RetentionPolicy_New SET @RetentionPolicy = @RetentionPolicy_New
IF @RetentionPolicy < 1 SET @RetentionPolicy = 1
DECLARE @RetentionDate datetime = DATEADD(MONTH, -@RetentionPolicy, GETUTCDATE())
PRINT CONCAT('Current Retention Policy: ',@RetentionPolicy,' months. New Retention Policy: ',@RetentionPolicy_New,' months. Keeping data newer than ',CAST(@RetentionDate AS NVARCHAR))
IF OBJECT_ID (N'[monitor].[PerfSampleLow]', N'U') IS NOT NULL
BEGIN
	PRINT 'Clearing unpartitioned data'
      EXEC monitor.sp_perf_sample_delete 2, @RetentionDate
	  EXEC monitor.sp_perf_sample_delete 3, @RetentionDate
END
ELSE
BEGIN
	PRINT 'Clearing partitioned data'
	DECLARE @cur CURSOR
	SET @cur = CURSOR LOCAL FOR SELECT 'monitor.' + [name] FROM sys.tables WHERE (name LIKE 'PerfSampleLow%') or (name LIKE 'PerfSampleDay%')
	OPEN @cur
	DECLARE @partitionName NVARCHAR(32)
	FETCH NEXT FROM @cur INTO @partitionName
	WHILE @@FETCH_STATUS = 0
	BEGIN
		DECLARE @sql NVARCHAR(MAX)
		--Truncate the section
		SET @sql = N'IF @RetentionDate >= (SELECT max([timestamp]) from ' + @partitionName + ') TRUNCATE TABLE ' + @partitionName
		EXEC sp_executesql @sql, N'@RetentionDate DATETIME', @RetentionDate
		--Delete the data from the remaining section (to fully meet the Retention Policy) + shrink the log
		IF (@StrictCleanup = 1) BEGIN
			SET @sql = N'DELETE from ' + @partitionName + ' where [timestamp] < @RetentionDate'
			EXEC sp_executesql @sql, N'@RetentionDate DATETIME', @RetentionDate
			IF (SELECT recovery_model FROM sys.databases where database_id = DB_ID()) = 3
				DBCC SHRINKDATABASE (0,TRUNCATEONLY) WITH NO_INFOMSGS
		END
		FETCH NEXT FROM @cur INTO @partitionName
	END
	CLOSE @cur
END
UPDATE common.ServerSettings SET RetentionPolicyPeriod = @RetentionPolicy_New
DBCC SHRINKDATABASE (0)  WITH NO_INFOMSGS
GO